# fields/uploaders -- lintian check script (rewrite) -*- perl -*-
#
# Copyright (C) 2004 Marc Brockschmidt
#
# Parts of the code were taken from the old check script, which
# was Copyright (C) 1998 Richard Braakman (also licensed under the
# GPL 2 or higher)
#
# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program.  If not, you can find it on the World Wide
# Web at https://www.gnu.org/copyleft/gpl.html, or write to the Free
# Software Foundation, Inc., 51 Franklin St, Fifth Floor, Boston,
# MA 02110-1301, USA.

package Lintian::Check::Fields::Uploaders;

use v5.20;
use warnings;
use utf8;

use Moo;
use namespace::clean;

with 'Lintian::Check';

sub always {
    my ($self) = @_;

    return
      unless $self->processable->fields->declares('Uploaders');

    my $uploaders = $self->processable->fields->value('Uploaders');

    # Note, not expected to hit on uploaders anymore, as dpkg
    # now strips newlines for the .dsc, and the newlines don't
    # hurt in debian/control

    # check for empty field see  #783628
    if ($uploaders =~ /,\s*,/) {
        $self->hint('uploader-name-missing','you have used a double comma');
        $uploaders =~ s/,\s*,/,/g;
    }

    if ($self->processable->fields->declares('Maintainer')) {

        my $maintainer = $self->processable->fields->value('Maintainer');

        $self->hint('maintainer-also-in-uploaders')
          if $uploaders =~ m/\Q$maintainer/;
    }

    return;
}

sub source {
    my ($self) = @_;

    return
      unless $self->processable->fields->declares('Uploaders');

    my $debian_control = $self->processable->debian_control;

    return
      unless $debian_control->source_fields->declares('Uploaders');

    my $uploaders = $debian_control->source_fields->value('Uploaders');
    my $control_position
      = $debian_control->source_fields->position('Uploaders');
    my $control_pointer = $debian_control->item->pointer($control_position);

    # check for empty field see  #783628
    if ($uploaders =~ /,\s*,/) {
        $self->pointed_hint('uploader-name-missing',$control_pointer,
            'you have used a double comma');
        $uploaders =~ s/,\s*,/,/g;
    }

    return;
}

1;

# Local Variables:
# indent-tabs-mode: nil
# cperl-indent-level: 4
# End:
# vim: syntax=perl sw=4 sts=4 sr et
