# masitainer-scripts/systemctl -- lintian check script -*- perl -*-
#
# Copyright (C) 2013 Michael Stapelberg
# Copyright (C) 2016-2020 Chris Lamb <lamby@debian.org>
# Copyright (C) 2021 Felix Lechner
#
# based on the apache2 checks file by:
# Copyright (C) 2012 Arno Toell
#
# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program.  If not, you can find it on the World Wide
# Web at https://www.gnu.org/copyleft/gpl.html, or write to the Free
# Software Foundation, Inc., 51 Franklin St, Fifth Floor, Boston,
# MA 02110-1301, USA.

package Lintian::Check::MaintainerScripts::Systemctl;

use v5.20;
use warnings;
use utf8;

use Moo;
use namespace::clean;

with 'Lintian::Check';

sub visit_control_files {
    my ($self, $item) = @_;

    return
      unless $item->is_maintainer_script;

    # look only at shell scripts
    return
      unless $item->hashbang =~ /^\S*sh\b/;

    my @lines = split(/\n/, $item->decoded_utf8);

    my $position = 1;
    for my $line (@lines) {

        next
          if $line =~ /^#/;

        my $pointer = $item->pointer($position);

        # systemctl should not be called in maintainer scripts at all,
        # except for systemctl daemon-reload calls.
        $self->pointed_hint('maintainer-script-calls-systemctl', $pointer)
          if $line =~ /^(?:.+;)?\s*systemctl\b/
          && $line !~ /daemon-reload/;

    } continue {
        ++$position;
    }

    return;
}

1;

# Local Variables:
# indent-tabs-mode: nil
# cperl-indent-level: 4
# End:
# vim: syntax=perl sw=4 sts=4 sr et
